Define the slide as a function.

slide[t_] := { Cos[4t], Sin[4t], 10-t^2 }

slide[0]

slide[Pi]

N[{1,0,10-(π^2)}]

See what the slide looks like.

ParametricPlot3D[ slide[t], {t,0,Pi}]

Find the derivative of the slide, and save it as a function.

D[ slide[t], t ]

slidePrime[t_] = D[ slide[t], t ]

slidePrime[0]

The difference between “=” and “:=”. Use “:=” when you want the value of the variable or function to be recomputed every time you ask for it, using the current values of variables it references. Usually this is what you want for functions you define. Use “=” if you want to evaluate the right-hand side of the “=” once, when you first execute the statement. This is good for functions if the function is the result of some computation, e.g., taking a derivative or antiderivative. Here are some examples, using numeric values rather than functions:

x = 1

x+3

y = x + 3

x = 2

y

y := x + 3

y

x = 1

y

Back to the slide: We’re also going to want the unit tangent to the slide, which involves dividing the tangent vector by its magnitude.

Norm[ slidePrime[t] ]

Mathematica is very resistant to simplifying this, particularly to getting rid of the absolute value operations. So simplify by hand and save the result as a “magnitude of the derivative” function.

slidePrimeMag[t_] := 2 Sqrt[t^2 + 4]

Now calculate the unit tangent vector and save as a function.

tangent[t_] = slidePrime[t] / slidePrimeMag[t]

The curvature is the magnitude of the derivative of the unit tangent over the magnitude of the derivative of the slide.

tPrime[t_] = D[ tangent[t], t ]

k[t_] = Norm[tPrime[t]]/slidePrimeMag[t]

k[0]

N[((Sqrt[65])/8)]

k[Pi]

N[k[Pi]]