Saving a Movie of an Animated Pendulum

ClearAll["Global`*"];

g=9.8; len=1; rb=0.05;         (* all the same physics as before... *)
period=2 π (Sqrt[(len/g)]);  amplitude = 0.5 ; ϕ[t_]:=amplitude Cos[((2 π t)/period)];
framecount = 100;timestep= (period/framecount);   (* new info for making the movie! *)

Here, I've decided to make a video that is exactly one oscillation period in duration. 
Also, I've decided to make the movie possess 100 frames. So if the period is 2.0 seconds (which it is...),
then each frames will be separated by a time Δt = 0.02 seconds. 

Warning! this notebook doesn't even bother to show the user what is being made!
You should also always use "animate" or "manipulate" to make sure it's what you want!

plotbob[t_]:=Graphics[{{Thick,Blue,Line[{{0,len},{len Sin[ϕ[t]],len (1-Cos[ϕ[t]])}}]},{PointSize[rb/len],Red,Point[{len Sin[ϕ[t]],len (1-Cos[ϕ[t]])}]}},Frame->False, PlotRange ->{{-len ,len},{-.25len,1.25len}}];
myframes=Table[plotbob[t],{t,0,period,timestep}];

Note the use of ":=" again.

path = "C:\\Users\\pogo@geneseo.edu\\Desktop\\pendulum.gif";
Export[path,myframes,"DisplayDurations"->0.0200,"AnimationRepetitions"->∞];

"DisplayDurations" tries to specify the amount of time, in seconds, that each frame of the animation will be displayed. So, if DisplayDurations is 2 seconds, and you have 30 frames, then the resulting gif file will run for one minute.  Note also that the last setting includes an auto-replay setting, which means that the movie will replay over and over. Because we're creating exactly one period of motion, this will then look like a pendulum swinging forever.

A "typical" video frame duration is 0.03333 seconds, resulting in a 30 frames per second animation. Here, we have 100 frames that should require 2 seconds to play, if the pendulum is moving in "real time". So, this video wants a frame rate of 50 fps. That means that our single frame duration should be 1/50 = 0.02 seconds. However, many computer playback tools ignore this data for avi and mp4 videos, meaning that they'll actually play back at 30 fps (Δt = 0.0333) rather than the desired 50 fps. At least the gif comes out correct!

Some format options are gif, avi, mov, mp4.
gif looks very nice, but won't "run" when double-clicked. It should be embedded into PowerPoint, or a web browser.
It's also a pretty large file size.
avi isn't even a real movie format, it's a movie "container". It is intended for insertion into a web page *)
mov might require Mathematica to be able to talk to Apple's "Quicktime" during the run to create.
I think the mp4 and the mov might be the same thing, or maybe the mp4 is somewhat compressed.